我认为我找到了一种方法来调整@EdMorton“copy_array”的实现，使其变成可以“展平”真正的多维数组的东西：

$ cat flatten.awk
BEGIN {
    arr["a"]["a"] = 21
    arr["a"]["b"] = 21
    arr["b"]["a"] = 2
    arr["b"]["b"] = 3
    arr["c"]["a"] = 4
    arr["d"]["x"]["y"]= 90
    arr["d"]["x"]["z"]= 95


    walk_array(arr, "arr")

    PROCINFO["sorted_in"]="@val_num_asc"
    flatten_array(arr, flatten)

    print "----------"

    walk_array(flatten, "flatten")
}

function flatten_array(orig, flatten, idx,      i)
{
    for (i in orig) {
        if (isarray(orig[i])) {
            flatten_array(orig[i], flatten, (idx=="" && idx==0) ? i : (idx SUBSEP i) )
        }
        else {
            #printf("idx->[%s]\n", idx) > "/dev/stderr"
            flatten[idx SUBSEP i] = orig[i]
        }
    }
}

function walk_array(arr, name,      i)
{
    for (i in arr) {
        if (isarray(arr[i]))
            walk_array(arr[i], (name "[" i "]"))
        else
            printf("%s[%s] = %s\n", name, i, arr[i])
    }
}

$ gawk -f flatten.awk
arr[a][a] = 21
arr[a][b] = 21
arr[b][a] = 2
arr[b][b] = 3
arr[c][a] = 4
arr[d][x][y] = 90
arr[d][x][z] = 95
----------
flatten[ba] = 2
flatten[bb] = 3
flatten[ca] = 4
flatten[aa] = 21
flatten[ab] = 21
flatten[dxy] = 90
flatten[dxz] = 95

不是特别优雅，但是…除非其他人可以提供替代方案……

使用标准作为新函数的模板flatten_array()：

awk '
BEGIN { #### sample multi-dimensional array

        arr["a"]["a"] = 21
        arr["a"]["b"] = 21
        arr["b"]["a"] = 2
        arr["b"]["b"] = 3
        arr["c"]["a"] = 4
        arr["d"] = 19
        arr["e"]["f"]["g"]["h"] = 14

        flatten_array(arr, "arr")

        #### OP mentions needing to sort the (flattened) array by value ...

        print "############ @val_num_desc"

        PROCINFO["sorted_in"] = "@val_num_desc"                 # sort arrFlat[] by numeric value in descending order
        for (ndx in arrFlat)
            printf "arrFlat[%s] = %s\n", ndx,arrFlat[ndx]

        print "############ @val_num_asc"

        PROCINFO["sorted_in"] = "@val_num_asc"                  # sort arrFlat[] by numeric value in ascending order
        for (ndx in arrFlat)
            printf "arrFlat[%s] = %s\n", ndx,arrFlat[ndx]
      }

function flatten_array(arr, name, ndx,     i)
{
    for (i in arr) {
        new_ndx = ndx (ndx=="" ? "" : ",") i                    # "," is a literal comma; replace "," with SUBSEP if you wish to use the system default delimiter
        if (isarray(arr[i]))
            flatten_array(arr[i], (name "[" i "]"), new_ndx )
        else
            arrFlat[new_ndx] = arr[i]
    }
}
'

笔记：

• 回复：索引分隔符 – 逗号与 SUBSEP：
• new_ndx = ndx (ndx=="" ? "" : ",") i– 这使用文字逗号作为索引分隔符，这在打印数组索引时是可见的
• new_ndx = ndx (ndx=="" ? "" : SUBSEP) i– 这将使用 awk 的标准索引分隔符\034，但它通常不会在打印到 stdout 时显示
• "a" SUBSEP "b"通常会显示为，ab但是如果你通过管道传输，od -c你会看到a \034 b
• 如果索引不包含逗号，那么 OP 应该能够根据显示（标准输出）要求使用任一分隔符（逗号、SUBSEP）
• 回复：目标数组名称：
• 目标数组名称（ ）在函数arrFlat[]中硬编码flatten_array()
• 目标数组名称的参数化留给读者练习
• 提示：请参阅或，了解参数化数组名称的方法

这将生成：

############ @val_num_desc
arrFlat[a,b] = 21
arrFlat[a,a] = 21
arrFlat[d] = 19
arrFlat[e,f,g,h] = 14
arrFlat[c,a] = 4
arrFlat[b,b] = 3
arrFlat[b,a] = 2
############ @val_num_asc
arrFlat[b,a] = 2
arrFlat[b,b] = 3
arrFlat[c,a] = 4
arrFlat[e,f,g,h] = 14
arrFlat[d] = 19
arrFlat[a,a] = 21
arrFlat[a,b] = 21

假设您不需要能够以交互方式执行此操作，也许这就是您要找的。我试图弄清楚如何将数组作为输入传递给此脚本，因为我认为这无法以交互方式工作，尽管也许其他人可以采用它并对其进行一些改进。

编辑：好的，我刚刚写了 shell 脚本。

#!/bin/bash

# In case you need to do this programmatically 
if [ -z "$1" ]; then
    echo "Usage: $0 '<input array to flatten>'"
    echo "Example: $0 'arr[\"a\"][\"a\"]=21; \
               arr[\"a\"][\"b\"]=21; arr[\"b\"][\"a\"]=2; \
               arr[\"b\"][\"b\"]=3; arr[\"c\"][\"a\"]=4; \
               arr[\"c\"][\"d\"][\"e\"]=10;'"
    exit 1
fi


array_definition="$1"

# Temporary file 
gawk_script="temp_flatten_sort.awk"

# create a temporary custom hardcoded script
cat << EOF > "$gawk_script"
# Recursive function to flatten multi-dimensional arrays
function flatten_array(src, dest, prefix, key, flat_key) {
    for (key in src) {
        if (isarray(src[key])) {
            flat_key = (prefix == "") ? key : prefix "," key
            flatten_array(src[key], dest, flat_key)
        } else {
            flat_key = (prefix == "") ? key : prefix "," key
            dest[flat_key] = src[key]
        }
    }
}

BEGIN {
   
    $array_definition

    delete flattened_array  # Initialize the flattened array

   
    flatten_array(arr, flattened_array)

    # Sort by values
    n = 0
    for (k in flattened_array) {
        n++
        keys[n] = k
    }
    for (i = 1; i <= n; i++) {
        for (j = i + 1; j <= n; j++) {
            if (flattened_array[keys[i]] > flattened_array[keys[j]]) {
                temp = keys[i]
                keys[i] = keys[j]
                keys[j] = temp
            }
        }
    }

    # Print
    for (i = 1; i <= n; i++) {
        print "flattened_array[\"" keys[i] "\"] =", flattened_array[keys[i]]
    }
}
EOF

# exec
gawk -f "$gawk_script"
# cleanup
rm "$gawk_script"

现在，你可以运行它：

$./flatten.sh 'arr["a"]["a"]=21; arr["a"]["b"]=21; arr["b"]["a"]=2; arr["b"]["b"]=3; arr["c"]["a"]=4; arr["c"]["d"]["e"]=10;'