假设：

• DTSTART / DTEND可能发生在任何地方，包括外部BEGIN:VEVENT / END:EVENT但…
• 我们只对一对DTSTART / DTEND中出现的条目感兴趣BEGIN:VEVENT / END:VEVENT
• 在一BEGIN:VEVENT / END:VEVENT对中，4x 所需的数据点可能按任何顺序甚至丢失（如果这不是真的，那么建议的解决方案可能有点矫枉过正，但它仍然应该生成所需的结果）

OP 尚未提供curl调用的实际输出，因此我将复制/修改 azbarcea 的数据集：

$ cat curl.out
BEGIN:VCALENDAR
VERSION:2.0
PRODID:-//Example Corp.//iCal4j 1.0//EN
CALSCALE:GREGORIAN

BEGIN:VEVENT
DTSTAMP:20240502T120000Z
DTSTART:20240502T090000Z
DTEND:20240505T100000Z
SUMMARY:Team Meeting
DESCRIPTION:Weekly team meeting to discuss progress and upcoming tasks.
LOCATION:Conference Room
UID:1234567890
SEQUENCE:0
END:VEVENT

        # scramble order of entries; remove SUMMARY

BEGIN:VEVENT
DESCRIPTION:Present our latest project updates to the client.
DTSTART:20240510T140000Z
DTEND:20240510T160000Z
DTSTAMP:20240502T120000Z
LOCATION:Client's Office
UID:0987654321
SEQUENCE:0
END:VEVENT

END:VCALENDAR

一个awk想法：

cat curl.out | awk -v date="${today}" '

function parse_dt(dt) {                                         # reformat the ICS datetime string

  if (dt ~ /[0-9]{8}T[0-9]{6}Z/)
     return substr(dt,1,4)  ":"  \
            substr(dt,5,2)  ":"  \
            substr(dt,7,2)  ":"  \
            substr(dt,10,2) ":"  \
            substr(dt,12,2) ":"  \
            substr(dt,14,2)
}

function print_event() {

    if (event[1] != "") {                                       # if we have a match (ie, DSTART == date) then print array
       print event[1]                                           # event[1] == DTSTART
       for (i=2;i<=4;i++)                                       # event[2] == DTEND
           if (event[i] != "")                                  # event[3] == SUMMARY
              print event[i]                                    # event[4] == DESCRIPTION
    }

    delete event                                                # clear/reset array
}

BEGIN        { FS =":"
               map["SUMMARY"]     = 3
               map["DESCRIPTION"] = 4
             }

$2=="VEVENT" { if ($1 == "BEGIN")                               # we are only interested in DSTART/DTEND pairs within a BEGIN:VEVENT/END:VEVENT pair
                  inEvent = 1

               else
               if ($1 == "END" ) {
                  print_event()
                  inEvent = 0
               }

               next
             }

inEvent      { if ($1 == "DTSTART" && index($2,date) > 0)
                  event[1] = "start:" parse_dt($2)

               else
               if ($1 == "DTEND")
                  event[2] = "end:" parse_dt($2)

               else
               if ($1 in map)                                   # SUMMARY or DESCRIPTION ?
                  event[map[$1]] = $0
             }
'

注意： OP 将替换cat curl.out |为curl -s "$ics_curl" |

准备试驾…

因为today=20240502我们得到：

start:2024:05:02:09:00:00
end:2024:05:05:10:00:00
SUMMARY:Team Meeting
DESCRIPTION:Weekly team meeting to discuss progress and upcoming tasks.

因为today=20240510我们得到：

start:2024:05:10:14:00:00
end:2024:05:10:16:00:00
DESCRIPTION:Present our latest project updates to the client.

因为today=20240505我们得到：

-- no ouput

如果这不能满足 OP 的要求，那么 OP 可能需要用更多详细信息更新问题（例如，调用的实际输出curl、完整的预期输出集）。

每当你的输入中有标签值对时，就像在这种情况下一样，我发现最好首先创建一个数组将标签（例如"DTSTART"）映射到它们的关联值（v[]如下），然后你可以比较、打印、修改你喜欢的任何值只需通过适当的标签对数组进行索引即可。使用任何 POSIX awk：

$ cat tst.sh
#!/usr/bin/env bash

today=$(date +%Y%m%d)

# replace this `cat` with your `curl` command
cat input.txt |
awk -v date="$today" '
    {
        if ( match($0,/^[[:upper:]]+:/) ) {
            tag = substr($0,RSTART,RLENGTH-1)
            v[tag] = substr($0,RSTART+RLENGTH)
        }
        else {
            v[tag] = v[tag] ORS $0
        }
    }
    /^END:VEVENT/ {
        if ( v["DTSTART"]+0 == date ) {
            print "start:"   dfmt(v["DTSTART"])
            print "end:"     dfmt(v["DTEND"])
            print "SUMMARY:" v["SUMMARY"] ORS v["DESCRIPTION"] ORS
        }
        delete v
    }
    function dfmt(date) { return \
        substr(date,10,2) ":" \
        substr(date,12,2)
    }
'

即使您的输入包含多行DESCRIPTION或任何其他字段（假设它符合提供的输入的修改版本：

$ cat input.txt
BEGIN:VCALENDAR
VERSION:2.0
PRODID:-//Example Corp.//iCal4j 1.0//EN
CALSCALE:GREGORIAN
BEGIN:VEVENT
DTSTAMP:20240502T120000Z
DTSTART:20240503T090000Z
DTEND:20240505T100000Z
SUMMARY:Team Meeting
DESCRIPTION:Weekly team meeting to
        discuss progress and
 upcoming tasks.
LOCATION:Conference Room
UID:1234567890
SEQUENCE:0
END:VEVENT
BEGIN:VEVENT
DTSTAMP:20240502T120000Z
DTSTART:20240510T140000Z
DTEND:20240510T160000Z
SUMMARY:Client
 Presentation
DESCRIPTION:
 Present our latest project
        updates to the client.
LOCATION:Client's Office
UID:0987654321
SEQUENCE:0
END:VEVENT
END:VCALENDAR

我们会得到这样的输出：

$ ./tst.sh
start:09:00
end:10:00
SUMMARY:Team Meeting
Weekly team meeting to
        discuss progress and
 upcoming tasks.

显然，您可以调整它以调整空白和/或输出日期格式，但是您喜欢，我将 和SUMMARY部分组合DESCRIPTION在一个输出块中，因为这就是问题中的代码的作用，但当然您可以单独打印它们。

关于问题中的脚本：

1. 你永远不需要做/regexp/ { sub(/regexp/, string); whatever }，你可以做sub(/regexp/, string) { whatever }以避免重复，/regexp/因为在这两种情况下，sub()只会做一些事情，并且只有在匹配时才会执行/regexp/。这适用于sub()s您的脚本中的两者
2. 您可以删除整个BEGIN部分，因为 awk 会自动将这些变量初始化为零或 null，因此手动执行此操作不会为您的脚本添加任何功能。
3. 您应该在每个部分中使用ORS而不是硬编码，以便这些部分将使用脚本其余部分使用的任何设置，而不是希望/假设将是。"\n"eventBuffer = eventBuffer "\n" $0ORSORS\n

我将AWK按照以下方式利用 GNU 来完成这项任务，让file.txt内容成为

start:20240502T080000Z

end:20240502T090000Z

SUMMARY:Event

然后

awk 'BEGIN{FS=OFS=":"}$1=="start"||$1=="end"{gsub(/[TZ]/,"");$0=gensub(/([0-9][0-9])/,":\\1","g");$0=gensub(/::([0-9][0-9]):/,":\\1",1)}{print}' file.txt

给出输出

start:2024:05:02:08:00:00

end:2024:05:02:09:00:00

SUMMARY:Event

说明：我通知 GNUAWK这:既是字段分隔符 ( FS) 又是输出字段分隔符 ( OFS)。当遇到start或end在第一个字段中时，我删除所有T并Z使用 gsub，然后使用为每对数字添加前缀:，然后再次使用它删除:第一个（多余）和第二个（年内）之前的内容。

我还添加了一个选项，将 UTC +0 时间转换为不同的时区（在我的例子中为 +2 UTC）。

     timeshift="2"

     start1 = substr(start, 10, 2);
     start2 = substr(start, 12, 2);
     start1= start1+timeshift;
 
     end1 = substr(end, 10, 2);
     end2 = substr(end, 12, 2);
     end1= end1+timeshift;